1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
|
/* strlen(str) -- determine the length of the string STR.
Copyright (C) 2002, 2003 Free Software Foundation, Inc.
Based on i486 version contributed by Ulrich Drepper <drepper@redhat.com>.
This file is part of the GNU C Library.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, write to the Free
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
02111-1307 USA. */
#include "_glibc_inc.h"
/* Seems to be unrolled too much */
.text
ENTRY (strlen)
movq %rdi, %rcx /* Duplicate source pointer. */
andl $7, %ecx /* mask alignment bits */
movq %rdi, %rax /* duplicate destination. */
jz 1f /* aligned => start loop */
neg %ecx /* We need to align to 8 bytes. */
addl $8,%ecx
/* Search the first bytes directly. */
0: cmpb $0x0,(%rax) /* is byte NUL? */
je 2f /* yes => return */
incq %rax /* increment pointer */
decl %ecx
jnz 0b
1: movq $0xfefefefefefefeff,%r8 /* Save magic. */
/* Align loop. */
/* Next 3 insns are 10 bytes total, make sure we decode them in one go */
.p2align 4,,10
4:
/* Main Loop is unrolled 4 times. */
/* First unroll. */
movq (%rax), %rcx /* get double word (= 8 bytes) in question */
addq $8,%rax /* adjust pointer for next word */
movq %r8, %rdx /* magic value */
addq %rcx, %rdx /* add the magic value to the word. We get
carry bits reported for each byte which
is *not* 0 */
jnc 3f /* highest byte is NUL => return pointer */
xorq %rcx, %rdx /* (word+magic)^word */
orq %r8, %rdx /* set all non-carry bits */
incq %rdx /* add 1: if one carry bit was *not* set
the addition will not result in 0. */
jnz 3f /* found NUL => return pointer */
/* Second unroll. */
movq (%rax), %rcx /* get double word (= 8 bytes) in question */
addq $8,%rax /* adjust pointer for next word */
movq %r8, %rdx /* magic value */
addq %rcx, %rdx /* add the magic value to the word. We get
carry bits reported for each byte which
is *not* 0 */
jnc 3f /* highest byte is NUL => return pointer */
xorq %rcx, %rdx /* (word+magic)^word */
orq %r8, %rdx /* set all non-carry bits */
incq %rdx /* add 1: if one carry bit was *not* set
the addition will not result in 0. */
jnz 3f /* found NUL => return pointer */
/* Third unroll. */
movq (%rax), %rcx /* get double word (= 8 bytes) in question */
addq $8,%rax /* adjust pointer for next word */
movq %r8, %rdx /* magic value */
addq %rcx, %rdx /* add the magic value to the word. We get
carry bits reported for each byte which
is *not* 0 */
jnc 3f /* highest byte is NUL => return pointer */
xorq %rcx, %rdx /* (word+magic)^word */
orq %r8, %rdx /* set all non-carry bits */
incq %rdx /* add 1: if one carry bit was *not* set
the addition will not result in 0. */
jnz 3f /* found NUL => return pointer */
/* Fourth unroll. */
movq (%rax), %rcx /* get double word (= 8 bytes) in question */
addq $8,%rax /* adjust pointer for next word */
movq %r8, %rdx /* magic value */
addq %rcx, %rdx /* add the magic value to the word. We get
carry bits reported for each byte which
is *not* 0 */
jnc 3f /* highest byte is NUL => return pointer */
xorq %rcx, %rdx /* (word+magic)^word */
orq %r8, %rdx /* set all non-carry bits */
incq %rdx /* add 1: if one carry bit was *not* set
the addition will not result in 0. */
jz 4b /* no NUL found => continue loop */
/* Align, it is a jump target. */
/* Next 3 insns are 8 bytes total, make sure we decode them in one go */
.p2align 3,,8
3:
subq $8,%rax /* correct pointer increment. */
testb %cl, %cl /* is first byte NUL? */
jz 2f /* yes => return */
incq %rax /* increment pointer */
testb %ch, %ch /* is second byte NUL? */
jz 2f /* yes => return */
incq %rax /* increment pointer */
testl $0x00ff0000, %ecx /* is third byte NUL? */
jz 2f /* yes => return pointer */
incq %rax /* increment pointer */
testl $0xff000000, %ecx /* is fourth byte NUL? */
jz 2f /* yes => return pointer */
incq %rax /* increment pointer */
shrq $32, %rcx /* look at other half. */
testb %cl, %cl /* is first byte NUL? */
jz 2f /* yes => return */
incq %rax /* increment pointer */
testb %ch, %ch /* is second byte NUL? */
jz 2f /* yes => return */
incq %rax /* increment pointer */
testl $0xff0000, %ecx /* is third byte NUL? */
jz 2f /* yes => return pointer */
incq %rax /* increment pointer */
2:
subq %rdi, %rax /* compute difference to string start */
ret
END (strlen)
libc_hidden_def(strlen)
|
