1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
|
/* Copyright (C) 2003, 2004 Free Software Foundation, Inc.
This file is part of the GNU C Library.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, write to the Free
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
02111-1307 USA. */
#include <sysdep.h>
#include <pthread-errnos.h>
#include <tcb-offsets.h>
#include "lowlevel-atomic.h"
#define SYS_gettimeofday __NR_gettimeofday
#define FUTEX_WAIT 0
#define FUTEX_WAKE 1
.text
.globl __new_sem_wait
.type __new_sem_wait,@function
.align 5
cfi_startproc
__new_sem_wait:
/* First check for cancellation. */
stc gbr, r0
mov.w .Lchand, r1
mov.l @(r0,r1), r0
mov #0xf9, r1
and r1, r0
cmp/eq #8, r0
bt 5f
mov.l r8, @-r15
cfi_adjust_cfa_offset(4)
cfi_rel_offset (r8, 0)
mov.l r10, @-r15
cfi_adjust_cfa_offset(4)
cfi_rel_offset (r10, 0)
mov.l r12, @-r15
cfi_adjust_cfa_offset(4)
cfi_rel_offset (r12, 0)
sts.l pr, @-r15
cfi_adjust_cfa_offset(4)
cfi_rel_offset (pr, 0)
mov r4, r8
3:
mov.l @r8, r0
2:
tst r0, r0
bt 1f
mov r0, r3
mov r0, r4
add #-1, r3
CMPXCHG (r4, @r8, r3, r2)
bf/s 2b
mov r2, r0
bra 9f
mov #0, r0
1:
mov.l .Lenable0, r1
bsrf r1
nop
.Lenable0b:
mov r0, r10
mov r8, r4
mov #FUTEX_WAIT, r5
mov #0, r6
mov #0, r7
mov #SYS_futex, r3
extu.b r3, r3
trapa #0x14
SYSCALL_INST_PAD
mov.l .Ldisable0, r1
mov r10, r4
bsrf r1
mov r0, r10
.Ldisable0b:
mov r10, r0
tst r0, r0
bt 3b
cmp/eq #-EWOULDBLOCK, r0
bt 3b
neg r0, r0
mov r0, r8
mova .Lgot0, r0
mov.l .Lgot0, r12
add r0, r12
#if USE___THREAD
mov.l .Lerrno0, r0
stc gbr, r1
mov.l @(r0, r12), r0
bra .Lexit
add r1, r0
.align 2
.Lerrno0:
.long errno@GOTTPOFF
.Lexit:
#else
mov.l .Lerrloc0, r1
bsrf r1
nop
.Lerrloc0b:
#endif
mov.l r8, @r0
mov #-1, r0
9:
lds.l @r15+, pr
mov.l @r15+, r12
mov.l @r15+, r10
rts
mov.l @r15+, r8
5:
/* Canceled. */
stc gbr, r0
mov.w .Lresult, r1
mov #-1, r2
mov.l r2, @(r0,r1)
mov.w .Lchand, r0
or.b #0x10, @(r0,gbr)
stc gbr, r0
mov.w .Lclbuf, r1
mov.l .Lunwind, r2
braf r2
mov.l @(r0,r1), r4
.Lunwindb:
cfi_endproc
.Lchand:
.word CANCELHANDLING - TLS_PRE_TCB_SIZE
.Lresult:
.word RESULT - TLS_PRE_TCB_SIZE
.Lclbuf:
.word CLEANUP_JMP_BUF - TLS_PRE_TCB_SIZE
.align 2
.Lgot0:
.long _GLOBAL_OFFSET_TABLE_
#if !USE___THREAD
.Lerrloc0:
.long __errno_location@PLT-(.Lerrloc0b-.)
#endif
.Lenable0:
.long __pthread_enable_asynccancel-.Lenable0b
.Ldisable0:
.long __pthread_disable_asynccancel-.Ldisable0b
.Lunwind:
.long HIDDEN_JUMPTARGET (__pthread_unwind)-.Lunwindb
.size __new_sem_wait,.-__new_sem_wait
weak_alias(__new_sem_wait, sem_wait)
|
