summaryrefslogtreecommitdiff
path: root/libc/sysdeps/linux/arm/clone.S
blob: eacf3dba643416fadcf35ccd5f4638d8b16dcd4e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
/* Copyright (C) 1996, 1997, 1998, 1999 Free Software Foundation, Inc.
   This file is part of the GNU C Library.
   Contributed by Pat Beirne <patb@corelcomputer.com>

   The GNU C Library is free software; you can redistribute it and/or
   modify it under the terms of the GNU Lesser General Public
   License as published by the Free Software Foundation; either
   version 2.1 of the License, or (at your option) any later version.

   The GNU C Library is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
   Lesser General Public License for more details.

   You should have received a copy of the GNU Lesser General Public
   License along with the GNU C Library; if not, see
   <http://www.gnu.org/licenses/>.  */

/* clone() is even more special than fork() as it mucks with stacks
   and invokes a function in the right context after its all over.  */

#include <sysdep.h>
#define _ERRNO_H
#include <features.h>
#include <bits/errno.h>
#include <sys/syscall.h>
#include <bits/arm_asm.h>
#include <bits/arm_bx.h>

#if defined(__NR_clone)
/* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg); */

.text
.global __clone
.type __clone,%function
.align 2
#if defined(THUMB1_ONLY)
.thumb_func
__clone:
	@ sanity check args
	cmp	r0, #0
	beq	__einval
	cmp	r1, #0
	beq	__einval

	@ insert the args onto the new stack
	sub	r1, r1, #8
	str	r3, [r1, #4]
	@ save the function pointer as the 0th element
	str	r0, [r1]

	@ do the system call
	@ get flags
	mov	r0, r2
	@ new sp is already in r1
	DO_CALL (clone)
	movs	a1, a1
	blt	__error
	beq	1f
	bx	lr
1:

	@ pick the function arg and call address off the stack and execute
	ldr	r0, [sp, #4]
#if defined(ARCH_HAS_BX)
	ldr	r1, [sp]
	bl	2f	@ blx r1
#else
	mov     lr, pc
	ldr     pc, [sp]
#endif

	@ and we are done, passing the return value through r0
	bl	HIDDEN_JUMPTARGET(_exit)
	@ Should never return
	b	.

2:
	bx	r1

__einval:
	ldr	r0, =-EINVAL
__error:
	push	{r3, lr}
	bl	__syscall_error
	POP_RET
.pool
#else
__clone:
.fnstart
.cantunwind
	@ sanity check args
	cmp	r0, #0
	IT(te, ne)
	cmpne	r1, #0
	moveq	r0, #-EINVAL
	beq	__error

	@ insert the args onto the new stack
	str	r3, [r1, #-4]!
	str	r0, [r1, #-4]!

	@ do the system call
	@ get flags
	mov	r0, r2
	@ new sp is already in r1
	push	{r4, r7}
	cfi_adjust_cfa_offset (8)
	cfi_rel_offset (r4, 0)
	cfi_rel_offset (r7, 4)
	ldr	r2, [sp, #8]
	ldr	r3, [sp, #12]
	ldr	r4, [sp, #16]
	ldr	r7, =SYS_ify(clone)
	swi	0x0
	cfi_endproc
	cmp	r0, #0
	beq	1f
	pop	{r4, r7}
	blt	__error
	IT(t, ne)
	BXC(ne, lr)

	cfi_startproc
.fnend
PSEUDO_END (__clone)

1:
	.fnstart
	.cantunwind
	@ pick the function arg and call address off the stack and execute
	ldr	r0, [sp, #4]
#if defined(__FDPIC__)
	ldr	r12, [sp]
	mov	r4, r9
	ldr	r9, [r12, #4]
	mov	lr, pc
	ldr	pc, [r12]
#else
	mov	lr, pc
	ldr 	pc, [sp]
#endif

#if defined(__FDPIC__)
	mov	r9, r4
#endif

	@ and we are done, passing the return value through r0
	b	HIDDEN_JUMPTARGET(_exit)

__error:
	b	__syscall_error
#endif

.size __clone,.-__clone
weak_alias(__clone, clone)

#endif